PC Toledo

Código: Selecionar todos

#pragma /w2
#pragma /es2

//#include 'boni_cmd.ch'
#include 'hbclass.ch'

#define __DFE_NFE_CERT_DIG__   iif(File('certificado.pfx'), Lower(PathAtual()) + 'certificado.pfx', '')
#define __DFE_NFE_CERT_SENHA__ iif(File('certificado.pfx'), '12345678', '')
#define __DFE_NFE_TBAMB__      2
#define __DFE_NFE_CUF__        32
#define __DFE_NFE_VERSAO__     '4.00'

CREATE CLASS DFe

CLASS VAR CertDigArq   INIT __DFE_NFE_CERT_DIG__   //AS TYPE CHARACTER
CLASS VAR CertDigSenha INIT __DFE_NFE_CERT_SENHA__ //AS TYPE CHARACTER 

CLASS VAR TpAmb        INIT __DFE_NFE_TBAMB__      //AS TYPE NUMERIC  // 1-Producao, 2-Homologacao
CLASS VAR CUF          INIT __DFE_NFE_CUF__        //AS TYPE NUMERIC
CLASS VAR Versao       INIT __DFE_NFE_VERSAO__     //AS TYPE CHARACTER

//VAR oDFe PROTECTED INIT NIL   // [[EXPORTED | VISIBLE] | [PROTECTED] | [HIDDEN]] [READONLY | RO]

VAR ConfBasica
VAR DFeError
VAR Error

VAR Certificado
VAR CertDigSel

VAR consStatServ
VAR statusServico

VAR DanfeConf
VAR DanfeServ

METHOD New() CONSTRUCTOR
DESTRUCTOR Destroy

METHOD CarregarCertificadoA1

METHOD Status
METHOD Danfe

//ON ERROR ErrorHandler()

ENDCLASS

/*
METHOD ErrorHandler(e) CLASS DFe
Self:Error := e
RETURN Self
*/

METHOD New(nServico, sCertDigArq, sCertDigSenha) CLASS DFe
LOCAL aCert, xx

//Self:oDFe := CriaVarObjectTemp()
DEFAULT nServico      TO 0 // 0=nfe status serviço, 5=Envio de evento
DEFAULT sCertDigArq   TO Self:CertDigArq
DEFAULT sCertDigSenha TO Self:CertDigSenha

Self:DFeError := CreateObject("Unimake.Exceptions.ThrowHelper")

//colocar certififcado na pasta do sistema "certififcado_cliente_tal-senha.pfx", carrega automático sem precisar configurar
//EX: "certificado_teste-12345678.pfx"
IF Empty(sCertDigArq)
  aCert := Directory('certificado*.pfx')
  IF Len(aCert) > 0
    sCertDigArq := ''
    FOR xx := 1 TO Len(aCert)
      sCertDigArq += (',' + Left(aCert[xx, 1], Rat('-', aCert[xx, 1]) - 1))
    NEXT
    sCertDigArq := SubStr(sCertDigArq, 2)
    IF Len(aCert) = 1
      xx := 1
    ELSE
      xx := Alerta('Certificados encontrados', Split(sCertDigArq, ','))
    ENDIF
    IF xx > 0
      sCertDigArq   := aCert[xx, 1]
      sCertDigSenha := SubStr(aCert[xx, 1], Rat('-', aCert[xx, 1]) + 1)
      sCertDigSenha := Left(sCertDigSenha, Len(sCertDigSenha) - 4)
      Self:CertDigArq := sCertDigArq
      Self:CertDigSenha := sCertDigSenha
    ELSE
      sCertDigArq := ''
    ENDIF
  ENDIF
ENDIF

* Criar configuração básica para consumir o serviço
Self:ConfBasica = CreateObject("Unimake.Business.DFe.Servicos.Configuracao")
Self:ConfBasica:TipoDfe := 0 // 0=nfe
Self:ConfBasica:Servico := nServico
Self:ConfBasica:CertificadoArquivo := sCertDigArq
Self:ConfBasica:CertificadoSenha   := sCertDigSenha

Self:CarregarCertificadoA1()

RETURN Self


METHOD Destroy() CLASS DFe

Self:ConfBasica := NIL
Self:DFeError := NIL
Self:Error := NIL

Self:Certificado := NIL
Self:CertDigSel := NIL

Self:consStatServ := NIL
Self:statusServico := NIL

Self:DanfeConf := NIL
Self:DanfeServ := NIL

RETURN Self


METHOD CarregarCertificadoA1(sCertDigArq, sCertDigSenha) CLASS DFe

DEFAULT sCertDigArq TO Self:ConfBasica:CertificadoArquivo
DEFAULT sCertDigSenha   TO Self:ConfBasica:CertificadoSenha

* Criar objeto com Certificado A1 informado
Self:Certificado := CreateObject("Unimake.Security.Platform.CertificadoDigital")
Self:CertDigSel := Self:Certificado:CarregarCertificadoDigitalA1(sCertDigArq, sCertDigSenha)

RETURN Self


METHOD Status(nTpAmb, nUf, sVersao) CLASS DFe

DEFAULT nTpAmb  TO Self:tpAmb
DEFAULT nUf     TO Self:CUF
DEFAULT sVersao TO Self:Versao

// Criar XML
Self:consStatServ = CreateObject("Unimake.Business.DFe.Xml.NFe.ConsStatServ")
Self:consStatServ:Versao := sVersao
Self:consStatServ:TpAmb  := nTpAmb
Self:consStatServ:CUF    := nUf

* Consumir o serviço
Self:statusServico := CreateObject("Unimake.Business.DFe.Servicos.NFe.StatusServico")
Self:statusServico:Executar(Self:consStatServ, Self:ConfBasica)

RETURN Self


METHOD Danfe(sArqXML, lImprimir, lVisualizar, lExecutar ) CLASS DFe

DEFAULT sArqXML     TO ''
DEFAULT lImprimir   TO .F.
DEFAULT lVisualizar TO .T.
DEFAULT lExecutar   TO .T.

* Configuracoes
Self:DanfeConf := CreateObject('Unimake.Unidanfe.Configurations.UnidanfeConfiguration')
Self:DanfeConf:Arquivo = sArqXML
Self:DanfeConf:Imprimir = lImprimir
Self:DanfeConf:Visualizar = lVisualizar

* Executar Impressao
Self:DanfeServ = CreateObject('Unimake.Unidanfe.UnidanfeServices')
IF lExecutar .and. !Empty(Self:DanfeConf:Arquivo)
  Self:DanfeServ:Execute(Self:DanfeConf)
ENDIF

RETURN Self

Código: Selecionar todos

PROCEDURE TesteDllDFe()
LOCAL oDFe, oError

BEGIN SEQUENCE WITH {|e| Break(e)}
  ? procline(0)
  oDFe := DFe()
  oDFe:New()
  //TesteDLLDFe_ValidarCertificadoA1(oDFe)
  TesteDLLDFe_Status(oDFe)
  TesteDLLDFe_Danfe(oDFe)
RECOVER USING oError
  ? oError:Description
  ? oError:Operation
  IF !Empty(oDFe:Error)
    ? oDFe:Error:Description
    ? oDFe:Error:Operation
  ENDIF
  ? oDFe:DFeError:GetMessage()
  ? oDFe:DFeError:GetErrorCode()
END SEQUENCE

RETURN


PROCEDURE TesteDLLDFe_Status(oDFe)
LOCAL oError

BEGIN SEQUENCE WITH {|e| Break(e)}
  oDFe:Status()
  ? "XML Retornado pela SEFAZ"
  ? "========================"
  ? oDFe:statusServico:RetornoWSString
  ?
  ? "Codigo de Status e Motivo"
  ? "========================="
  ? AllTrim(Str(oDFe:statusServico:Result:CStat, 5))
  ? oDFe:statusServico:Result:XMotivo
  ?
RECOVER USING oError
  ? oError:Description
  ? oError:Operation
  IF !Empty(oDFe:Error)
    ? oDFe:Error:Description
    ? oDFe:Error:Operation
  ENDIF
  ? oDFe:DFeError:GetMessage()
  ? oDFe:DFeError:GetErrorCode()
END SEQUENCE

RETURN


PROCEDURE TesteDLLDFe_ValidarCertificadoA1(oDFe)
Local Certificado, CertificadoSelecionado

True(oDFe)

* Criar objeto com Certificado A1 informado
Certificado := CreateObject("Unimake.Security.Platform.CertificadoDigital")
CertificadoSelecionado := Certificado:CarregarCertificadoDigitalA1(oDFe:CertDigArq, oDFe:CertDigSenha)

//? "ID do Certificado....: ", oDFe:Certificado:GetThumbPrint(oDFe:CertDigSel)
? "ID do Certificado....: ", Certificado:GetThumbPrint(CertificadoSelecionado) //oDFe:CertDigSel
? "Dados do proprietario: ", Certificado:GetSubject(CertificadoSelecionado)
? "Numero de Serie......: ", Certificado:GetSerialNumber(CertificadoSelecionado)
? "Validade Inicial.....: ", Certificado:GetNotBefore(CertificadoSelecionado)
? "Validade Final.......: ", Certificado:GetNotAfter(CertificadoSelecionado)
? "Certificado vencido?.: ", Certificado:Vencido(CertificadoSelecionado)
?

RETURN


PROCEDURE TesteDLLDFe_Danfe(oDFe)

oDFe:Danfe('.\arquivo_nfe.xml', .F./*imprimir*/, .T./*visualizar*/, .T./*executar*/)

RETURN